PDF Dosyalarını Birleştirme

23 Temmuz 2021 1658

PDF Dosyalarını Birleştirme isimli kod, farklı farklı isimlerde kaydedilmiş pdf dosyalarını Excel üzerinden birleştirme işlevini görmektedir.

Sub Main()
  Dim MyFiles As String, DestFile As String
  With ActiveSheet
    MyFiles = .Range("A1").Value & "," & .Range("B1").Value
    DestFile = .Range("C1").Value
  End With
  Call MergePDFs01(MyFiles, DestFile)
End Sub

Sub MergePDFs01(MyFiles As String, DestFile As String)
  Dim a As Variant, i As Long, n As Long, ni As Long
  Dim AcroApp As New Acrobat.AcroApp, PartDocs() As Acrobat.AcroPDDoc

  a = Split(MyFiles, ",")
  ReDim PartDocs(0 To UBound(a))

  On Error GoTo exit_
  If Len(Dir(DestFile)) Then Kill DestFile
  For i = 0 To UBound(a)
    If Dir(Trim(a(i))) = "" Then
      MsgBox "File not found" & vbLf & a(i), vbExclamation, "Canceled"
      Exit For
    End If
    Set PartDocs(i) = New Acrobat.AcroPDDoc
    PartDocs(i).Open Trim(a(i))
    If i Then
      ni = PartDocs(i).GetNumPages()
      If Not PartDocs(0).InsertPages(n - 1, PartDocs(i), 0, ni, True) Then
        MsgBox "Cannot insert pages of" & vbLf & a(i), vbExclamation, "Canceled"
      End If
      n = n + ni
      PartDocs(i).Close
      Set PartDocs(i) = Nothing
    Else
      n = PartDocs(0).GetNumPages()
    End If
  Next

  If i > UBound(a) Then
    If Not PartDocs(0).Save(PDSaveFull, DestFile) Then
      MsgBox "Cannot save the resulting document" & vbLf & DestFile, vbExclamation, "Canceled"
    End If
  End If

exit_:

  If Err Then
    MsgBox Err.Description, vbCritical, "Error #" & Err.Number
  ElseIf i > UBound(a) Then
    MsgBox "The resulting file is created:" & vbLf & DestFile, vbInformation, "Done"
  End If

  If Not PartDocs(0) Is Nothing Then PartDocs(0).Close
  Set PartDocs(0) = Nothing
  AcroApp.Exit
  Set AcroApp = Nothing

End Sub

Gerekli Adımlar

Kodu çalıştırmanız için aşağıdaki adımları yerine getirmeniz gerekir.

  1. Microsoft Visual Basic for Applications penceresini (Alt + F11) açın.
  2. Project - VBAProject alanının, ekranın sol tarafında görüldüğünden emin olun. Görünmüyorsa, Ctrl + R kısayolu ile hızlıca açın.
  3. Araç çubuklarından Insert -> Module yazısına tıklayın.
  4. Solunda klasör simgesi olan Modules yazısının başındaki + simgesine tıklayın.
  5. Alt kısma eklenecek gelecek olan Module(1) yazısına çift tıklayın.
  6. Üstteki kodu yapıştırın.

Kod Açıklaması

image-20210723022842-1.png

Üst resimdeki gibi alanları kendinize göre doldurup, örnek kodları çalıştırabilirsiniz.

Hazır Dosyayı İndir

Dosyayı indirmek için giriş yapmanız ve VIP Üyelik Paketine sahip olmanız gerekir.
50 Farklı Hazır Makro (VBA) Kodu
Etkin Sayfa Hariç Çalışma Sayfalarını Gizleme
Hücre Aralığını Görüntüye Dönüştürme
Toplama İşlemi Yapan Kullanıcı Tanımlı Fonksiyon
Excel Makroları ile Klasör Silme
Yanıp Sönme Efekti Verme Kodu
Birleştirilmiş Hücrelerin Başlangıç Bitiş Sütununu Belirleme
Dolar Okutma Makrosu
Seçimdeki Alternatif Satırları Vurgulama
İçindekiler Tablosu Oluşturma
Ondalık Sayıları Tam Sayıya Çevirme
Bir Dizeden Sayısal Veriler Elde Etme
Sütunu Kes Kopyala ve Yapıştır
R1C1 Referans Stilini Etkinleştirme
Zaman Aralığı Ekleme
Çalışma Sayfaları için Yakınlaştırma Yüzdesini Ayarlama
Gizlenmiş Makro Örnekleri
Excel Hücresini Seçme Makrosu
Excel Makro Modulü Silme Kodu
Çalışma Kitabındaki Tüm Çalışma Sayfalarını Koruma
Seçili Satırların Sayısını Bulma
TextBox Nesnelerinin Arasında Boşluk Bırakma
Excel Satır Silme Kodu
Transparan UserForm Oluşturmak
Excel Makroları ile İşlemci Bilgilerini Bulma
Boş Hücrelerin Görünmez Alanını Vurgulama
Birden Çok Sütun Ekleme
Bir Aralıktaki Maksimum Değeri Renklendirme
Excel Makroları ile Dosya Sayısını Bulma
Kullanıcı Adınızı Bulma
Çalışma Sayfalarını Tek Adımda Korumasını Kaldırma
Birden Çok Satır Ekleme
Tek Satırı Kes Kopyala ve Yapıştır
Sayılara Yeni Bir Sayı Ekleme
Aç Penceresini Açan Makro
Makrolar ile Klasör Kopyalama
Hücredeki Değişikliklerin Kaydını Tutma
Aktif Hücreye Günün Tarihini Yazma
Seçili Aralığa Ait Bilgilerin Listelenmesi
Excel Makroları ile Dosya Taşıma
Sayıların Önündeki Tek Tırnak İşaretini Kaldırma
X Sayı Atlayarak Satır Gizleme
Yorumları Yazdırma
Belirli Kriterlere Sahip Satırları Silme
Excel Kitabındaki Sayfa Adlarının Listelenmesi
Select Case Kullanımı
Api ile Bilgisayar Adını Bulmak
Tek Hücreyi Kes Kopyala ve Yapıştır
Kaydedilmemiş Açık Çalışma Kitaplarını Sayma
Txt Dosyası Oluşturma
Metin Sarmayı Kaldırma

Daha önce yorum yapılmamış!

Backlink Reklam Bu alanda 50 karakterlik açıklama ile web sitenize ait Backlink Reklam yayınlayabilirsiniz.
Yükleniyor...